GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
# Local configure fragment for sysdeps/powerpc32/elf.

if test "$usetls" != no; then
# Check for support of thread-local storage handling in assembler and
# linker.
AC_CACHE_CHECK(for powerpc32 TLS support, libc_cv_powerpc32_tls, [dnl
cat > conftest.s <<\EOF
	.section ".tdata","awT",@progbits
x:	.long	1
x1:	.long	1
x2:	.long	1
	.text
	addi	3,31,x@got@tlsgd
	addi	3,31,x1@got@tlsld
	addi	9,3,x1@dtprel
	addis	9,3,x2@dtprel@ha
	addi	9,9,x2@dtprel@l
	lwz	0,x1@dtprel(3)
	addis	9,3,x2@dtprel@ha
	lwz	0,x2@dtprel@l(9)
	lwz	9,x3@got@tprel(31)
	add	9,9,x@tls
	addi	9,2,x1@tprel
	addis	9,2,x2@tprel@ha
	addi	9,9,x2@tprel@l
EOF
dnl
if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
  libc_cv_powerpc32_tls=yes
else
  libc_cv_powerpc32_tls=no
fi
rm -f conftest*])
if test $libc_cv_powerpc32_tls = yes; then
  AC_DEFINE(HAVE_TLS_SUPPORT)
fi
fi
