dnl
dnl $Id: configure.ac,v 3.112 2006-01-05 12:01:23 airlied Exp $
dnl
dnl Copyright © 2003 Keith Packard
dnl
dnl Permission to use, copy, modify, distribute, and sell this software and its
dnl documentation for any purpose is hereby granted without fee, provided that
dnl the above copyright notice appear in all copies and that both that
dnl copyright notice and this permission notice appear in supporting
dnl documentation, and that the name of Keith Packard not be used in
dnl advertising or publicity pertaining to distribution of the software without
dnl specific, written prior permission.  Keith Packard makes no
dnl representations about the suitability of this software for any purpose.  It
dnl is provided "as is" without express or implied warranty.
dnl
dnl KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
dnl INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
dnl EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
dnl CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
dnl DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
dnl TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
dnl PERFORMANCE OF THIS SOFTWARE.
dnl
dnl Process this file with autoconf to create configure.

AC_PREREQ(2.53)
AC_INIT([Xserver],6.6.1,[keithp@keithp.com],Xserver)
AC_CONFIG_SRCDIR([Makefile.am])
AM_INIT_AUTOMAKE([dist-bzip2])
AM_MAINTAINER_MODE
AM_CONFIG_HEADER(include/config.h)

AC_PROG_CC
AM_PROG_AS
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_YACC
AC_PROG_LEX
AC_LIBTOOL_WIN32_DLL
AM_PROG_LIBTOOL
AC_PROG_MAKE_SET

AC_HEADER_DIRENT
AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_BIGENDIAN([ENDIAN="X_BIG_ENDIAN"], [ENDIAN="X_LITTLE_ENDIAN"])

AC_CHECK_SIZEOF([unsigned long])
if test "$ac_cv_sizeof_unsigned_long" = 8; then
	AC_DEFINE(_XSERVER64, 1, [Define to 1 if unsigned long is 64 bits.])
fi

AC_TYPE_PID_T

# Checks for library functions.
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
AC_FUNC_ALLOCA

# Find the math libary
AC_CHECK_LIB(m,sqrt)

AC_CHECK_HEADERS([ndbm.h dbm.h rpcsvc/dbm.h])

# VM86 headers
AC_CHECK_HEADERS([sys/vm86.h sys/io.h])

# AGPGART headers
AC_CHECK_HEADERS([linux/agpgart.h sys/agpio.h])

# APM header
AC_CHECK_HEADERS([linux/apm_bios.h])

# fbdev header
AC_CHECK_HEADERS([linux/fb.h])

# MTRR header
AC_CHECK_HEADERS([asm/mtrr.h])

# Handhelds.org touchscreen driver
AC_CHECK_HEADERS([linux/h3600_ts.h])

# tslib touchscreen driver
AC_CHECK_HEADERS([tslib.h])

REQUIRED_MODULES="randrproto renderproto fixesproto damageproto xextproto xfont xproto xtrans xau"
XGL_REQUIRED_MODULES="xrandr xrender xfixes xdamage xext"

DEFAULT_FONT_PATH="/usr/lib/X11/fonts/misc,/usr/lib/X11/fonts/100dpi,/usr/lib/X11/fonts/75dpi"
DEFAULT_MODULE_PATH="$libdir/modules"
DEFAULT_VENDOR_STRING="freedesktop.org"
DEFAULT_VENDOR_RELEASE="6710"
EXTENSION_LIBS='$(top_builddir)/Xext/libXext.a'
EXTENSION_INCS='-I$(top_srcdir)/Xext'

AC_ARG_ENABLE(werror,        [  --enable-werror ],[WERROR=$enableval],[WERROR=no])
AC_ARG_ENABLE(shape,         [  --disable-shape ],[SHAPE=$enableval],[SHAPE=yes])
AC_ARG_ENABLE(xv,            [  --disable-xv ],[XV=$enableval],[XV=yes])
AC_ARG_ENABLE(composite,     [  --disable-composite ],[COMPOSITE=$enableval],[COMPOSITE=yes])
AC_ARG_ENABLE(mitshm,        [  --disable-shm ],[MITSHM=$enableval],[MITSHM=yes])
AC_ARG_ENABLE(xres,          [  --disable-xres ],[RES=$enableval],[RES=yes])
AC_ARG_ENABLE(xrecord,       [  --disable-xrecord ],[RECORD=$enableval],[RECORD=yes])
AC_ARG_ENABLE(kdriveserver,  [  --disable-kdriveserver ],[KDRIVESERVER=$enableval],[KDRIVESERVER=yes])
AC_ARG_ENABLE(xnestserver,   [  --enable-xnestserver ],[XNESTSERVER=$enableval],[XNESTSERVER=no])
AC_ARG_ENABLE(xwinserver,    [  --enable-xwinserver ],[XWINSERVER=$enableval],[XWINSERVER=no])
AC_ARG_ENABLE(xsdlserver,    [  --enable-xsdlserver ],[XSDLSERVER=$enableval],[XSDLSERVER=no])
AC_ARG_ENABLE(xglserver,     [  --enable-xglserver ],[XGLSERVER=$enableval],[XGLSERVER=no])
AC_ARG_ENABLE(xglxserver,    [  --enable-xglxserver ],[XGLXSERVER=$enableval],[XGLXSERVER=no])
AC_ARG_ENABLE(xeglserver,    [  --enable-xeglserver ],[XEGLSERVER=$enableval],[XEGLSERVER=no])
AC_ARG_ENABLE(xtrap,         [  --enable-xtrap ],[XTRAP=$enableval],[XTRAP=no])
AC_ARG_ENABLE(builtinrgb,    [  --disable-builtinrgb ],[USE_RGB_BUILTIN=$enableval],[USE_RGB_BUILTIN=yes])
AC_ARG_ENABLE(screensaver,   [  --disable-screensaver ],
			     [SCREENSAVER=$enableval],
			     [SCREENSAVER=yes])
AC_ARG_ENABLE(xdmcp,         [  --disable-xdmcp ],[XDMCP=$enableval],[XDMCP=auto])
AC_ARG_ENABLE(xdm-auth-1,    [  --disable-xdm-auth-1 ],[XDMAUTH=$enableval],[XDMAUTH=auto])
AC_ARG_ENABLE(glx,           [  --enable-glx ],[GLX=$enableval],[GLX=no])
AC_ARG_ENABLE(dri,           [  --enable-dri ],[DRI=$enableval],[DRI=no])
AC_ARG_ENABLE(xinput,	     [  --enable-xinput ],[XINPUT=$enableval],[XINPUT=no])
AC_ARG_ENABLE(xkb,	     [  --enable-xkb ],[XKB=$enableval],[XKB=no])
AC_ARG_ENABLE(xloadable,     [  --enable-xloadable ],[XLOADABLE=$enableval],[XLOADABLE=no])
AC_ARG_ENABLE(xevie,         [  --enable-xevie ],[XEVIE=$enableval],[XEVIE=no])
AC_ARG_ENABLE(xinerama,	     [  --enable-xinerama ],[XINERAMA=$enableval],[XINERAMA=no])
AC_ARG_ENABLE(unix-transport,[  --disable-unix-transport ], [UNIXCONN=$enableval], [UNIXCONN=yes])
AC_ARG_ENABLE(tcp-transport, [  --disable-tcp-transport ], [TCPCONN=$enableval], [TCPCONN=yes])
AC_ARG_ENABLE(ipv6,          [  --disable-ipv6 ], [IPV6CONN=$enableval], [IPV6CONN=yes])
if test "$UNIXCONN" = "yes"; then
	AC_DEFINE(UNIXCONN,1,[Support UNIX socket connections])
fi
if test "$TCPCONN" = "yes"; then
	AC_DEFINE(TCPCONN,1,[Support TCP socket connections])
fi
if test "$IPV6CONN" = "yes"; then
	AC_DEFINE(IPv6,1,[Support IPv6 for TCP connections])
fi

AC_ARG_WITH(mesa-source,        [  --with-mesa-source=PATH ],
				[MESA_SOURCE="$withval"],
				[MESA_SOURCE="\$(top_srcdir)/GL/mesa"])
AC_ARG_WITH(fontpath,        [  --with-fontpath=PATH ],
				[FONTPATH="$withval"],
				[FONTPATH="$DEFAULT_FONT_PATH"])
AC_ARG_WITH(modulepath,         [  --with-modulepath=PATH ],
				[MODULEPATH="$withval"],
				[MODULEPATH="$DEFAULT_MODULE_PATH"])
AC_ARG_WITH(vendor-string,   [  --with-vendor-string=VENDOR ],
			     	[ VENDOR_STRING="$withval" ],
			     	[ VENDOR_STRING="$DEFAULT_VENDOR_STRING" ])
AC_ARG_WITH(vendor-release,  [  --with-vendor-release=RELEASE ],
				[ VENDOR_RELEASE="$withval" ],
				[ VENDOR_RELEASE="$DEFAULT_VENDOR_RELEASE" ])

AM_CONDITIONAL(SHAPE, test x$SHAPE = xyes)
if test "$SHAPE" = yes; then
	AC_DEFINE(SHAPE,1,[Support SHAPE extension])
fi

AM_CONDITIONAL(XV, [test x$XV = xyes])
if test "$XV" = yes; then
	AC_DEFINE(XV,1,[Support Xv Extension])
fi

AM_CONDITIONAL(COMPOSITE, [test x$COMPOSITE = xyes])
if test "$COMPOSITE" = yes; then
	AC_DEFINE(COMPOSITE,1,[Support Composite Extension])
	REQUIRED_MODULES="$REQUIRED_MODULES compositeproto"
	XGL_REQURIED_MODULES="$XGL_REQUIRED_MODULES xcomposite"
fi

AM_CONDITIONAL(MITSHM, [test x$MITSHM = xyes])
if test "$MITSHM" = yes; then
	AC_DEFINE(MITSHM,1,[Support MIT-SHM Extension])
fi

AM_CONDITIONAL(KDRIVESERVER, [test x$KDRIVESERVER = xyes])
if test "$KDRIVESERVER" = yes; then
	AC_DEFINE(KDRIVESERVER,1,[Build Kdrive X server])
	AC_DEFINE(KDRIVEDDXACTIONS,,[Build kdrive ddx])
fi

AM_CONDITIONAL(XNESTSERVER, [test x$XNESTSERVER = xyes])
if test "$XNESTSERVER" = yes; then
	AC_DEFINE(XNESTSERVER,,[Build Xnest server])
	XNEST_REQUIRED_MODULES="x11 xext"
fi

AM_CONDITIONAL(XSDLSERVER, [test x$XSDLSERVER = xyes])
if test "$XSDLSERVER" = yes; then
	AC_DEFINE(XSDLSERVER,,[Build XSDL server])
fi

AM_CONDITIONAL(XWINSERVER, [test x$XWINSERVER = xyes])
if test "$XWINSERVER" = yes; then
	AC_DEFINE(XWINSERVER,,[Build XWin server])
	XWIN_REQUIRED_MODULES="x11"
fi

XGL_REQUIRED_GLITZ_VERSION="0.5.2"
AM_CONDITIONAL(XGLSERVER, [test x$XGLSERVER = xyes])
if test "$XGLSERVER" = yes; then
	XLOADABLE=yes
	AC_DEFINE(XGLSERVER,1,[Build GL X server])
fi
XGL_REQUIRED_MODULES="$XGL_REQUIRED_MODULES glitz >= $XGL_REQUIRED_GLITZ_VERSION"

AM_CONDITIONAL(XGLXSERVER, [test x$XGLXSERVER = xyes])
if test "$XGLXSERVER" = yes; then
	AC_DEFINE(XGLXSERVER,1,[Build GLX X server])
fi
XGLX_REQUIRED_MODULES="glitz-glx >= $XGL_REQUIRED_GLITZ_VERSION xrender >= 0.5.0"

AM_CONDITIONAL(XEGLSERVER, [test x$XEGLSERVER = xyes])
if test "$XEGLSERVER" = yes; then
	AC_DEFINE(XEGLSERVER,1,[Build EGL X server])
fi
XEGL_REQUIRED_MODULES="glitz-egl >= $XGL_REQUIRED_GLITZ_VERSION"

AM_CONDITIONAL(XTRAP, [test x$XTRAP = xyes])
if test "$XTRAP" = yes; then
	AC_DEFINE(XTRAP,1,[Support XTrap extension])
fi

AM_CONDITIONAL(SCREENSAVER, [test x$SCREENSAVER = xyes])
if test "$SCREENSAVER" = yes; then
	AC_DEFINE(SCREENSAVER,1,[Support MIT-SCREEN-SAVER extension])
fi
AM_CONDITIONAL(RES, [test x$RES = xyes])
if test "$RES" = yes; then
	AC_DEFINE(RES,1,[Support X resource extension])
	REQUIRED_MODULES="$REQUIRED_MODULES resourceproto"
	XGL_REQUIRED_MODULES="$XGL_REQUIRED_MODULES xres"
fi

AM_CONDITIONAL(RECORD, [test x$RECORD = xyes])
if test "$RECORD" = yes; then
	AC_DEFINE(XRECORD,1,[Support X record extension])
	REQUIRED_MODULES="$REQUIRED_MODULES recordproto"
	EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/record'
	EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/record/librecord.a'
fi

AM_CONDITIONAL(GLX, test x$GLX = xyes)
if test "$GLX" = yes; then
	AC_DEFINE(GLXEXT,1,[Build GLX extension])
	GLX_INCS='-I$(top_srcdir)/GL/glx -I$(top_srcdir)/GL/include -I$(MESA_SOURCE)/include -I$(MESA_SOURCE)/src/mesa/glapi/'
	GLX_LIBS='$(top_builddir)/GL/glx/libglx.la $(top_builddir)/GL/mesa/libglcore.la'
fi
AC_SUBST([GLX_INCS])
AC_SUBST([GLX_LIBS])
AC_SUBST([MESA_SOURCE])

AM_CONDITIONAL(DRI, test x$DRI = xyes)
if test "$DRI" = yes; then
	AC_DEFINE(XF86DRI,1,[Build DRI extension])
	AC_DEFINE(_XF86DRI_SERVER_,1,[XF86DRI internal define])
fi

AM_CONDITIONAL(XINPUT, [test x$XINPUT = xyes])
if test "$XINPUT" = yes; then
	AC_DEFINE(XINPUT,1,[Support X Input extension])
	EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/Xi'
	EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/Xi/libXi.a'
fi

AM_CONDITIONAL(XKB, [test x$XKB = xyes])
if test "$XKB" = yes; then
	AC_DEFINE(XKB,1,[Support XKB extension])
	EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/xkb'
	EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/xkb/libxkb.a'
	REQUIRED_MODULES="$REQUIRED_MODULES xkbfile"
fi

AM_CONDITIONAL(XEVIE, [test x$XEVIE = xyes])
if test "$XEVIE" = yes; then
	AC_DEFINE(XEVIE,1,[Support XEVIE extension])
fi

AM_CONDITIONAL(XINERAMA, [test x$XINERAMA = xyes])
if test "$XINERAMA" = yes; then
	AC_DEFINE(XINERAMA,1,[Support Xinerama extension])
	AC_DEFINE(PANORAMIX,1,[Internal define for Xinerama])
	REQUIRED_MODULES="$REQUIRED_MODULES panoramixproto"
	XGL_REQUIRED_MODULES="$XGL_REQUIRED_MODULES panoramixext"
fi

AM_CONDITIONAL(XLOADABLE, [test x$XLOADABLE = xyes])
if test "$XLOADABLE" = yes; then
	AC_DEFINE(XLOADABLE,1,[Support loadable input and output drivers])
fi

PKG_CHECK_MODULES(XDMCP, xdmcp, [have_libxdmcp="yes"], [have_libxdmcp="no"])

if test "$have_libxdmcp" = yes; then
	AC_CHECK_LIB(Xdmcp, XdmcpWrap, [have_xdmcpwrap="yes"], [have_xdmcpwrap="no"], [$XDMCP_LIBS])
fi

if test x$XDMCP = xauto; then
	if test $have_libxdmcp = yes; then
		XDMCP=yes
	else
		XDMCP=no
	fi
fi
if test x$XDMAUTH = xauto; then
	if test $have_libxdmcp = yes -a x$have_xdmcpwrap = xyes; then
		XDMAUTH=yes
	else
		XDMAUTH=no
	fi
fi

AM_CONDITIONAL(XDMCP, [test x$XDMCP = xyes])
if test "$XDMCP" = yes; then
	AC_DEFINE(XDMCP,1,[Support Xdmcp])
	REQUIRED_MODULES="$REQUIRED_MODULES xdmcp"
fi

AM_CONDITIONAL(XDMAUTH, [test x$XDMAUTH = xyes])
if test "$XDMAUTH" = yes; then
	AC_DEFINE(HASXDMAUTH,1,[Support XDM-AUTH*-1])
	if test "x$XDMCP" != yes; then
		REQUIRED_MODULES="$REQUIRED_MODULES xdmcp"
	fi
fi

if test "$ac_cv_header_tslib_h" = yes; then
	AC_DEFINE(TSLIB, 1, [Include tslib touchscreen driver])
	TSLIB=yes
else
	TSLIB=no
fi

AM_CONDITIONAL(TSLIB, [test x$TSLIB = xyes])
if test "$TSLIB" = yes; then
	AC_DEFINE(TSLIB,1,[Support tslib touchscreen abstraction library])
else

dnl Make sure tslib and ipaq ts dont *both* get enabled.

	if test "$ac_cv_header_linux_h3600_ts_h" = yes; then
	   AC_DEFINE(H3600_TS, 1, [Include handhelds.org h3600 touchscreen driver])
	   H3600_TS=yes
	else
	   H3600_TS=no
fi

fi


AM_CONDITIONAL(H3600_TS, [test "$H3600_TS" = yes])
if test "$TSLIB" = yes -o "$H3600_TS" = yes; then
	AC_DEFINE(TOUCHSCREEN,1,[Enable touchscreen support])
fi

AM_CONDITIONAL(USE_RGB_BUILTIN, [test x$USE_RGB_BUILTIN = xyes])
if test "$USE_RGB_BUILTIN" = yes; then
	AC_DEFINE(USE_RGB_BUILTIN,1,[Use builtin rgb color database])
fi


PKG_CHECK_MODULES(XEPHYR, x11 xext, [xephyr="yes"], [xephyr="no"])
AM_CONDITIONAL(XEPHYR, [test "$xephyr" = yes])
AC_SUBST([XEPHYR_LIBS])
AC_SUBST([XEPHYR_INCS])


if test "$ac_cv_header_sys_vm86_h" = yes; then
	AC_DEFINE(KDRIVEVESA, 1, [Include vesa support in X servers])
fi
AM_CONDITIONAL(KDRIVEVESA, [test "$ac_cv_header_sys_vm86_h" = yes])

if test "$ac_cv_header_linux_fb_h" = yes; then
	AC_DEFINE(KDRIVEFBDEV, 1, [Include framebuffer support in X servers])
fi
AM_CONDITIONAL(KDRIVEFBDEV, [test "$ac_cv_header_linux_fb_h" = yes])

AC_DEFINE_UNQUOTED(COMPILEDDEFAULTFONTPATH, ["$FONTPATH"], [Default font path])
AC_DEFINE_UNQUOTED(VENDOR_STRING,["$VENDOR_STRING"], [Vendor name])
AC_DEFINE_UNQUOTED(VENDOR_RELEASE, [$VENDOR_RELEASE], [Vendor release])
AC_SUBST([MODULEPATH])

dnl
dnl A bunch of configuration values which shouldn't be optional
dnl
AC_DEFINE(RENDER,1,[Support RENDER extension])
EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/render/librender.a'
EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/render'

AC_DEFINE(RANDR,1,[Support RANDR extension])
EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/randr/librandr.a'
EXTENSION_INCS="$EXTENSION_INCS "-I'$(top_srcdir)/randr'

AC_DEFINE(DDXOSINIT,1,[Use OsVendorInit])
AC_DEFINE(SERVER_LOCK,1,[Use a lock to prevent multiple servers on a display])
AC_DEFINE(SMART_SCHEDULE,1,[Include time-based scheduler])
AC_DEFINE(NDEBUG,1,[Disable some debugging code])
AC_DEFINE(USE_RGB_TXT,1,[Use rgb.txt directly])
AC_DEFINE(MITMISC,1,[Support MIT Misc extension])
AC_DEFINE(XTEST,1,[Support XTest extension])
AC_DEFINE(XSYNC,1,[Support XSync extension])
AC_DEFINE(XCMISC,1,[Support XCMisc extension])
AC_DEFINE(BIGREQS,1,[Support BigRequests extension])
AC_DEFINE(PIXPRIV,1,[Support pixmap privates])
AC_DEFINE(XFIXES,1,[Support XFixes extension])
AC_DEFINE(PART_NET,1,[Tolerate partial network availability])
EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/xfixes/libxfixes.a'
EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/xfixes'

AC_DEFINE(DAMAGEEXT,1,[Support Damage extension])
EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/damageext/libdamageext.a'
EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/damageext'

if test "$COMPOSITE" = yes; then
	EXTENSION_LIBS="$EXTENSION_LIBS "'$(top_builddir)/composite/libcomposite.a'
	EXTENSION_INCS="$EXTENSION_INCS "'-I$(top_srcdir)/composite'
fi

if test "$TSLIB" = yes -a "$KDRIVESERVER" = "yes"; then
	PKG_CHECK_MODULES(XCALIBRATE, xcalibrateext, [enable_xcalibrate="yes"], [enable_xcalibrate="no"])
	if test "$enable_xcalibrate" = "yes"; then
		REQUIRED_MODULES="$REQUIRED_MODULES xcalibrateext"
		AC_DEFINE(HAVE_XCALIBRATE,1,[Enable XCalibrate extension])
	fi
fi
AM_CONDITIONAL(XCALIBRATE, [test "$enable_xcalibrate" = "yes"])

DIX_LIB='$(top_builddir)/dix/libdix.a'
OS_LIB='$(top_builddir)/os/libos.a'
MI_LIB='$(top_builddir)/mi/libmi.a'
MI_INC='-I$(top_srcdir)/mi'
FB_LIB='$(top_builddir)/fb/libfb.a'
FB_INC='-I$(top_srcdir)/fb'
DAMAGE_LIB='$(top_builddir)/miext/damage/libdamage.a'
DAMAGE_INC='-I$(top_srcdir)/miext/damage'
SHADOW_LIB='$(top_builddir)/miext/shadow/libshadow.a'
SHADOW_INC='-I$(top_srcdir)/miext/shadow'
XPSTUBS_LIB='$(top_builddir)/dix/libxpstubs.a'
XKB_LIB='$(top_builddir)/xkb/libxkb.a'
XI_LIB='$(top_builddir)/Xi/libXi.a'
XI_INC='-I$(top_builddir)/Xi'

PKG_CHECK_MODULES(XSERVER, $REQUIRED_MODULES)

XSERVER_LIBS="${XSERVER_LIBS} -lm -lz"
AC_SUBST([XSERVER_LIBS])

KDRIVE_LIBS=
KDRIVE_INCS=
KDRIVE_PURE_LIBS=
KDRIVE_PURE_INCS=
if test "$KDRIVESERVER" = yes; then
	KDRIVE_LIB='$(top_builddir)/hw/kdrive/src/libkdrive.a'
	KDRIVE_INC='-I$(top_srcdir)/hw/kdrive/src'
	KDRIVE_OS_LIB='$(top_builddir)/hw/kdrive/linux/liblinux.a'
	KDRIVE_OS_INC='-I$(top_srcdir)/hw/kdrive/linux'
	KDRIVE_PURE_LIBS="$DIX_LIB $OS_LIB $KDRIVE_LIB $KDRIVE_OS_LIB \
	                  $FB_LIB $MI_LIB $EXTENSION_LIBS $GLX_LIBS \
			  $DAMAGE_LIB $SHADOW_LIB $XPSTUBS_LIB"
	KDRIVE_PURE_INCS="$KDRIVE_INC $DAMAGE_INC $SHADOW_INC $EXTENSION_INCS \
	                  $GLX_INCS $FB_INC $MI_INC"
	KDRIVE_LIBS="$KDRIVE_PURE_LIBS $KDRIVE_OS_LIB"
	KDRIVE_INCS="$KDRIVE_PURE_INCS $KDRIVE_OS_INC"
fi
AC_SUBST([KDRIVE_PURE_LIBS])
AC_SUBST([KDRIVE_PURE_INCS])
AC_SUBST([KDRIVE_LIBS])
AC_SUBST([KDRIVE_INCS])

XNEST_LIBS=
XNEST_INCS=
if test "$XNESTSERVER" = yes; then
	PKG_CHECK_MODULES(XNESTSERVER, $XNEST_REQUIRED_MODULES)
	XNEST_LIBS="$DIX_LIB $OS_LIB $XNEST_LIB \
		$EXTENSION_LIBS $GLX_LIBS $MI_LIB \
		$EXTENSION_LIBS $DAMAGE_LIB $SHADOW_LIB $XPSTUBS_LIB"
	XNEST_INCS="$XNEST_INC $XNEST_OS_INC $DAMAGE_INC $SHADOW_INC \
		$EXTENSION_INCS $GLX_INCS $MI_INC"
fi
AC_SUBST([XNEST_LIBS])
AC_SUBST([XNEST_INCS])

XWIN_LIBS=
XWIN_INCS=
if test "$XWINSERVER" = yes; then
	PKG_CHECK_MODULES(XWINSERVER, $XWIN_REQUIRED_MODULES)
	XWIN_LIB='$(top_builddir)/hw/xwin/libxwin.a'
	XWIN_INC='-I$(top_srcdir)/hw/xwin'
	XWIN_LIBS="$DIX_LIB $OS_LIB $XWIN_LIB \
		$EXTENSION_LIBS $GLX_LIBS $FB_LIB $MI_LIB \
		$EXTENSION_LIBS $SHADOW_LIB $XPSTUBS_LIB -lcygipc"
	XWIN_INCS="$XWIN_INC $XWIN_OS_INC $SHADOW_INC \
		$EXTENSION_INCS $GLX_INCS $FB_INC $MI_INC"
fi
AC_SUBST([XWIN_LIBS])
AC_SUBST([XWIN_INCS])

XSDL_LIBS=
XSDL_INCS=
XSDL_DIRS=
if test "$XSDLSERVER" = yes; then
	XSDL_LIBS=`sdl-config --libs`
	XSDL_INCS=`sdl-config --cflags`
	XSDL_DIRS=sdl
fi
AC_SUBST([XSDL_LIBS])
AC_SUBST([XSDL_INCS])
AC_SUBST([XSDL_DIRS])

XGL=no
if test "$XGLSERVER" = yes -o "$XGLXSERVER" = yes -o "$XEGLSERVER" = yes; then
	XGL=yes
fi

XGL_LIBS=
XGL_INCS=
XGL_GLXEXT_LIB=
XGL_GLXEXT_INC=
AM_CONDITIONAL(XGL, [test "x$XGL" = xyes])
if test "x$XGL" = xyes; then
	PKG_CHECK_MODULES(XGLSERVER, $XGL_REQUIRED_MODULES)

	XGL_LIB='$(top_builddir)/hw/xgl/libxgl.a'
	XGL_INC='-I$(top_srcdir)/hw/xgl'

	XGL_LIBS="$XGL_LIB $DIX_LIB $OS_LIB $FB_LIB $MI_LIB \
		$EXTENSION_LIBS $DAMAGE_LIB $SHADOW_LIB $XPSTUBS_LIB"
	XGL_INCS="$XGL_INC $GLX_INCS $DAMAGE_INC $SHADOW_INC $EXTENSION_INCS \
		$FB_INC $MI_INC"

	if test "$XLOADABLE" = yes; then
		XGLSERVER_LIBS="$XSERVER_LIBS $XGLSERVER_LIBS -ldl"
	fi

	if test "x$GLX" = xyes; then
		XGL_GLXEXT_LIB='$(top_builddir)/hw/xgl/glxext/libxglglxext.la'
		XGL_GLXEXT_INC='-I$(top_builddir)/hw/xgl/glxext'
	fi
fi
AC_SUBST([XGL_LIBS])
AC_SUBST([XGL_INCS])

XGLX=$XGL
if test "x$XGLX" = xyes; then
	if test "$XGLXSERVER" = yes; then
		PKG_CHECK_MODULES(XGLXSERVER, $XGLX_REQUIRED_MODULES)
	else
		PKG_CHECK_MODULES(XGLXSERVER, $XGLX_REQUIRED_MODULES,
			[], [XGLX=no])
	fi
fi

XGLX_LIBS=
XGLX_INCS=
XGLX_MOD_LIBS=
AM_CONDITIONAL(XGLX, [test "x$XGLX" = xyes])
if test "x$XGLX" = xyes; then
	XGLX_LIB='$(top_builddir)/hw/xgl/glx/libxglx.la'
	XGLX_INC='-I$(top_srcdir)/hw/xgl/glx'
	XGLX_LIBS="$XGLX_LIB $XGL_GLXEXT_LIB $XGL_LIBS"
	XGLX_INCS="$XGLX_INC $XGL_GLXEXT_INC $XGL_INCS"
	XGLX_MOD_LIBS="$XGLX_LIB $XGL_GLXEXT_LIB"
fi
AC_SUBST([XGLX_LIBS])
AC_SUBST([XGLX_INCS])
AC_SUBST([XGLX_MOD_LIBS])

XEGL=$XGL
if test "x$XEGL" = xyes; then
	if test "$XEGLSERVER" = yes; then
		PKG_CHECK_MODULES(XEGLSERVER, $XEGL_REQUIRED_MODULES)
	else
		PKG_CHECK_MODULES(XEGLSERVER, $XEGL_REQUIRED_MODULES,
			[], [XEGL=no])
	fi
fi

XEGL_LIBS=
XEGL_INCS=
XEGL_MOD_LIBS=
AM_CONDITIONAL(XEGL, [test "x$XEGL" = xyes])
if test "x$XEGL" = xyes; then
	XEGL_INC='-I$(top_srcdir)/hw/xgl/egl'
	XEGL_LIB='$(top_builddir)/hw/xgl/egl/libxegl.la'
	XEGL_LIBS="$XEGL_LIB $XGL_GLXEXT_LIB $XGL_LIBS"
	XEGL_INCS="$XEGL_INC $XGL_GLXEXT_INC $XGL_INCS"
	XEGL_MOD_LIBS="$XEGL_LIB $XGL_GLXEXT_LIB"
fi
AC_SUBST([XEGL_LIBS])
AC_SUBST([XEGL_INCS])
AC_SUBST([XEGL_MOD_LIBS])


AC_CHECK_HEADERS([X11/XF86keysym.h],,,${XSERVER_CFLAGS})

XSERVER_CFLAGS="$XSERVER_CFLAGS -D_BSD_SOURCE "'-I${top_srcdir}/include -I${top_srcdir}/Xext'

if test "x$GCC" = "xyes"; then
	GCC_WARNINGS="-Wall -Wpointer-arith -Wstrict-prototypes \
	-Wmissing-prototypes -Wmissing-declarations \
	-Wnested-externs -fno-strict-aliasing"
	if test "x$WERROR" = "xyes"; then
		GCC_WARNINGS="${GCC_WARNINGS} -Werror"
	fi
	XSERVER_CFLAGS="$GCC_WARNINGS $XSERVER_CFLAGS"
fi

AC_MSG_CHECKING(if unaligned word accesses behave as expected)
AC_TRY_RUN([
#include <stdio.h>

int main()
{
        char j[8]={1,2,3,4,5,6,7,8};
        int k= *(int *)(j+1);
        if(k==0x02030405 || k==0x05040302)
                return 0;
        return 1;
}
],
 [AC_DEFINE(WORKING_UNALIGNED_INT, 1, [unaligned word accesses behave as expected])
  AC_MSG_RESULT(yes)],
 AC_MSG_RESULT(no),
 AC_MSG_RESULT(assuming not on target machine))

MMX_CFLAGS="-mmmx -Winline --param inline-unit-growth=10000 --param large-function-growth=10000"

have_mmx_intrinsics=no
AC_MSG_CHECKING(For MMX/SSE intrinsics in the compiler)
xserver_save_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS $MMX_CFLAGS"
AC_COMPILE_IFELSE([
#if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
#error "Need GCC >= 3.4 for MMX intrinsics"
#endif
#include <mmintrin.h>
int main () {
    __m64 v = _mm_cvtsi32_si64 (1);
    __m64 w = _mm_slli_si64 (v, 1);
    v = _mm_or_si64 (v, w);
    return _mm_cvtsi64_si32 (v);
}], have_mmx_intrinsics=yes)
CFLAGS=$xserver_save_CFLAGS
AC_MSG_RESULT($have_mmx_intrinsics)

if test $have_mmx_intrinsics = yes ; then
   AC_DEFINE(USE_MMX, 1, [use MMX compiler intrinsics])
else
   MMX_CFLAGS=
fi
AC_SUBST(MMX_CFLAGS)

AM_CONDITIONAL(USE_MMX, test $have_mmx_intrinsics = yes)

AC_OUTPUT([
Makefile
GL/Makefile
GL/glx/Makefile
GL/mesa/Makefile
include/Makefile
dix/Makefile
dri/Makefile
drm/Makefile
fb/Makefile
mi/Makefile
miext/Makefile
miext/damage/Makefile
miext/shadow/Makefile
os/Makefile
randr/Makefile
render/Makefile
record/Makefile
xfixes/Makefile
damageext/Makefile
composite/Makefile
xkb/Makefile
Xext/Makefile
Xi/Makefile
hw/Makefile
hw/kdrive/Makefile
hw/kdrive/src/Makefile
hw/kdrive/linux/Makefile
hw/kdrive/fbdev/Makefile
hw/kdrive/vesa/Makefile
hw/kdrive/ati/Makefile
hw/kdrive/mach64/Makefile
hw/kdrive/mga/Makefile
hw/kdrive/sdl/Makefile
hw/kdrive/smi/Makefile
hw/kdrive/nvidia/Makefile
hw/kdrive/r128/Makefile
hw/kdrive/chips/Makefile
hw/kdrive/fake/Makefile
hw/kdrive/neomagic/Makefile
hw/kdrive/pm2/Makefile
hw/kdrive/via/Makefile
hw/kdrive/i810/Makefile
hw/kdrive/epson/Makefile
hw/kdrive/ephyr/Makefile
hw/xnest/Makefile
hw/xwin/Makefile
hw/xgl/Makefile
hw/xgl/glxext/Makefile
hw/xgl/glxext/module/Makefile
hw/xgl/glx/Makefile
hw/xgl/glx/module/Makefile
hw/xgl/egl/Makefile
hw/xgl/egl/module/Makefile
])

if test "x$XGL" = xyes; then
	echo ""
	if test "$XGLSERVER" = yes; then
		echo "Xgl will be compiled with the following ddx modules:"
		echo "  xglx: $XGLX"
		echo "  xegl: $XEGL"
		echo ""
		echo "the following stand-alone servers:"
	else
		echo "The following stand-alone Xgl servers will be compiled:"
	fi
	echo "  Xglx: $XGLXSERVER"
	echo "  Xegl: $XEGLSERVER"
	echo ""
	echo "and the following extension modules:"
	echo "  glx: $GLX"
	echo ""
fi