AC_PREREQ(2.53)
AC_INIT(Dates, 0.4.2, http://www.pimlico-project.org/)
AM_INIT_AUTOMAKE()
AC_CONFIG_SRCDIR(src/dates_main.c)
AM_CONFIG_HEADER(src/config.h)
AM_MAINTAINER_MODE

AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CC_STDC
AC_STDC_HEADERS
AC_PROG_LIBTOOL
IT_PROG_INTLTOOL([0.35.0])

dnl I18n support
GETTEXT_PACKAGE=AC_PACKAGE_NAME
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext package])
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT

PKG_CHECK_MODULES(DATES, glib-2.0 gtk+-2.0 libecal-1.2 gconf-2.0)

PKG_CHECK_MODULES(GTK, gtk+-2.0)
AC_SUBST(GTK_CFLAGS)
AC_SUBST(GTK_LIBS)

# -- Hildon stuff for Maemo 
# we will use WITH_HILDON for #ifdef's in .c files and for any makefile conditionals
hildon=false
HILDON_CFLAGS=""
HILDON_LIBS=""

AC_ARG_ENABLE(hildon,AS_HELP_STRING([--enable-hildon],[Turn on hildon support]),[
	if test "x$enableval" = "xyes"; then
	   hildon=true
	   PKG_CHECK_MODULES(HILDON,[
				hildon-libs >= 0.12.0,
				dbus-1, 
				libosso, 
				libosso-gsf-1
				], 
				HAVE_HILDON=yes,HAVE_HILDON=no)

	   HILDON_CFLAGS="$HILDON_CFLAGS -DWITH_HILDON=1"
	   DATES_CFLAGS="$DATES_CFLAGS $HILDON_CFLAGS"
	   DATES_LIBS="$DATES_LIBS $HILDON_LIBS"
	   PLATFORM=hildon
	fi
])

AM_CONDITIONAL(WITH_HILDON, test "x$hildon" = "xtrue")

AC_ARG_ENABLE(owl, [AC_HELP_STRING([--enable-owl], 
	      [Use the OWL colour widgets])],
	      owl="$enableval",
	      owl=false)

AM_CONDITIONAL(USE_OWL, test "x$owl" = "xtrue")

# -- End of Hildon Stuff --

omoko=false
OMOKO_CFLAGS=""
OMOKO_LIBS=""

AC_ARG_ENABLE(omoko,AS_HELP_STRING([--enable-omoko],[Turn on OpenMoko support]),[
	if test "x$enableval" = "xyes"; then
	   omoko=true
	   PKG_CHECK_MODULES(OMOKO, openmoko-libs)

	   OMOKO_CFLAGS="$OMOKO_CFLAGS -DWITH_OMOKO=1 -DDATES_ABREV_DAY_LABELS=1"
	   DATES_CFLAGS="$DATES_CFLAGS $OMOKO_CFLAGS"
	   DATES_LIBS="$DATES_LIBS $OMOKO_LIBS"
	   PLATFORM=omoko
	fi
])


AM_CONDITIONAL(WITH_OMOKO, test "x$omoko" = "xtrue")

old_cflags=$CFLAGS
CFLAGS=$DATES_CFLAGS
AC_CHECK_TYPE(ECalComponentId, [], [], [#include <libecal/e-cal.h>])
CFLAGS=$old_cflags

if test $ac_cv_type_ECalComponentId = yes; then
        AC_DEFINE(HAVE_CID_TYPE, 1, [Defined if ECalComponentId exists])
fi

AC_ARG_ENABLE(debug,AS_HELP_STRING([--disable-debug],[disable debugging output]),[enable_debug=no],[enable_debug=yes])
if test x"$enable_debug" = "xyes"; then
	AC_DEFINE(DEBUG, 1, [Defined to enable debugging output])
fi

AC_ARG_ENABLE(dnd,AS_HELP_STRING([--disable-dnd],[disable drag and drop support]),[enable_dnd=no],[enable_dnd=yes])
if test x"$enable_dnd" = "xyes"; then
        AC_DEFINE(WITH_DND, 1, [Defined to enable drag and drop support])
fi

AC_SUBST(DATES_CFLAGS)
AC_SUBST(DATES_LIBS)

#default platform
if test x$PLATFORM = x ; then
   PLATFORM=gtk
fi

AM_CONDITIONAL(PLATFORM_GTK, test x$PLATFORM = xgtk)
AM_CONDITIONAL(PLATFORM_HILDON, test x$PLATFORM = xhildon)
AM_CONDITIONAL(PLATFORM_OMOKO, test x$PLATFORM = xomoko)

AC_CONFIG_FILES([
		Makefile
		data/Makefile
		po/Makefile.in
		data/com.openedhand.dates.service
		src/Makefile
		src/libgtkdatesview.pc
		libowl/Makefile
])

AC_OUTPUT

echo " "
AC_MSG_RESULT([Installing in: ${prefix}])

AC_MSG_RESULT([Platform front-end: ${PLATFORM}])

if test x"$enable_debug" = "xyes"; then
	AC_MSG_RESULT([Debugging output enabled.])
else
	AC_MSG_RESULT([Debugging output disabled.])
fi
if test x"$enable_dnd" = "xyes"; then
	AC_MSG_RESULT([Drag and drop support enabled.])
else
	AC_MSG_RESULT([Drag and drop support disabled.])
fi